Exploring AI with Groovy™

var ollama = new Ollama(requestTimeoutSeconds: 300)
println "Found ollama: ${ollama.ping()}"

Found ollama: true

var prompt = 'What are 4 interesting things to do while I am on vacation in Glasgow?'
var builder = OllamaChatRequest.builder()
    .withModel('mistral:7b')

var request = builder
    .withMessage(OllamaChatMessageRole.USER, prompt)
    .build()

var result = ollama.chat(request, null)
println "Four things:\n$result.responseModel.message.response"

Four things:
 1. Visit the Glasgow Cathedral: This historic cathedral is a must-see in Glasgow. It's one of the 5 great medieval churches
 of Scotland and offers a glimpse into the city's rich history. The adjoining Necropolis cemetery also provides stunning views of the city.

2. Explore the Kelvingrove Art Gallery and Museum: This world-class museum houses over 8,000 objects, including works by
artists like Botticelli, Monet, and Rembrandt. It's a great place to spend a day learning about art, history, and science.

3. Stroll through Glasgow Green Park: One of the city's oldest parks, Glasgow Green offers beautiful landscapes,
a bandstand, a skate park, and even a mini-golf course. It's a perfect spot for a picnic or a leisurely walk.

4. Take a tour of The Tenement House: This well-preserved Victorian dwelling provides a unique insight into the lives of
Glasgow's middle class during the early 20th century. The guided tours are informative and engaging, offering a glimpse into a bygone era.

var prompt2 = 'If I had half a day and can only go to one, which would you recommend?'
request = builder
    .withMessages(result.chatHistory)
    .withMessage(OllamaChatMessageRole.USER, prompt2)
    .build()

result = ollama.chat(request, null)
println "Best thing:\n$result.responseModel.message.response"

Best thing:
Given that you have only half a day and want to see a mix of history, culture, and local life, I would recommend visiting
the Kelvingrove Art Gallery and Museum. It's centrally located, easily accessible, and offers an extensive collection of
art and artifacts that provide a fascinating glimpse into Glasgow's past and present. Plus, it's free to enter, making it
a great value for your time.
If you prefer outdoor activities or want to experience the local vibe, Glasgow Green Park is another excellent choice.
You can take a leisurely stroll through the park, enjoy the scenery, and even grab a bite at one of the nearby cafes or food trucks.

var chatModel = OllamaChatModel.builder()
    .baseUrl("http://localhost:11434")
    .timeout(Duration.ofMinutes(5))
    .modelName("mistral:7b")
    .build()

String prompt = 'What are 4 interesting things to do while I am on vacation in Caloundra?'
println "Response:\n" + chatModel.chat(prompt)

Response:
 1. Visit the beautiful beaches: Caloundra is known for its stunning beaches, with Kings Beach and Moffat Beach being some of the most popular ones. You can spend your days sunbathing, swimming, or surfing.

2. Explore the underwater world: Take a trip to the UnderWater World Sea Life Mooloolaba, an aquarium that houses a variety of marine life including sharks, turtles, and seahorses. It's a great way to learn about and appreciate the ocean's wonders.

3. Visit the Glastonbury Estate: This historic homestead offers a glimpse into Australia's past. The estate features beautiful gardens, a tea room, and often hosts various events throughout the year.

4. Take a day trip to the Glass House Mountains: Just a short drive from Caloundra, these iconic volcanic plugs offer breathtaking views and hiking trails for all levels of fitness. You can also visit the Kondalilla National Park for waterfalls and rainforest walks.

var prompt = 'What are 4 interesting things to do while I am on vacation in Caloundra?'
var response = model.chat(new UserMessage(prompt))

var prompt2 = 'If I had half a day and can only go to one, which would you recommend?'
var response2 = model.chat(response.aiMessage(), new UserMessage(prompt2))

println """
Four things:
${response.aiMessage().text()}

Best thing:
${response2.aiMessage().text()}
"""

Best thing:
 If you only have half a day and can only choose one attraction, I would recommend visiting the UnderWater World SEA LIFE Mooloolaba. It's an excellent aquarium that offers a fascinating glimpse into the marine life of the region, and it's suitable for people of all ages.

The UnderWater World is home to a variety of marine animals, including sharks, turtles, stingrays, seahorses, and many more. You can also participate in interactive experiences such as feeding the sharks or holding a starfish. The aquarium also offers educational programs and behind-the-scenes tours for those interested in learning more about marine conservation.

While the Coastal Walk and Glass House Mountains are worth visiting if you have more time, they require more planning and travel time, so I would recommend UnderWater World SEA LIFE Mooloolaba as the best option for a half-day visit.

interface HolidayAssistant {
    String chat(String message)
}

var model = OllamaChatModel.builder()
    .baseUrl("http://localhost:11434")
    .timeout(Duration.ofMinutes(5))
    .modelName("mistral:7b")
    .build()

var chatMemory = MessageWindowChatMemory.withMaxMessages(10)

var assistant = AiServices.builder(HolidayAssistant)
    .chatModel(model)
    .chatMemory(chatMemory)
    .build()

var prompt = 'What are 4 interesting things to do while I am on vacation in Caloundra?'
var response = assistant.chat(prompt)

var prompt2 = '''
It might rain at some point on the weekend, so can you give me
a very short description of a single backup alternative if it rains?
Make it different to your previous suggestions since I am not
sure which ones I will have already seen by the time it rains.
'''
var response2 = assistant.chat(prompt2)

println """
Four things:
$response

If it rains:
$response2
"""

Four things:
 1. Visit the beautiful beaches: Caloundra is known for its stunning beaches, with Mooloolaba Beach and Kings Beach being particularly popular. You can spend your days swimming, sunbathing, or even surfing.

2. Explore the Underwater World SEA LIFE Sunshine Coast: This aquarium offers an amazing opportunity to get up close and personal with a variety of marine life, including sharks, stingrays, turtles, and seals.

3. Visit the Bulcock Beach Esplanade: This is a great spot for shopping, dining, and people-watching. The esplanade offers a range of boutiques, cafes, and restaurants. Don't forget to check out the local markets that are held regularly.

4. Take a day trip to Australia Zoo: Made famous by the Crocodile Hunter, Steve Irwin, this zoo is a must-visit for animal lovers. It's home to a wide variety of Australian wildlife and offers interactive experiences and shows throughout the day.

If it rains:
 If it rains, an indoor activity that you might enjoy is visiting the Queensland Air Museum in Caboolture, which is a short drive from Caloundra. The museum houses one of Australia's largest collections of aircraft and aviation artifacts, including military planes, helicopters, and memorabilia. It offers a fascinating look at the history of Australian aviation and is suitable for all ages.

interface HolidayBot {
    List<Activity> extractActivitiesFrom(String text)
}

var model = OllamaChatModel.builder()
    .baseUrl("http://localhost:11434")
    .supportedCapabilities(RESPONSE_FORMAT_JSON_SCHEMA)
    .timeout(Duration.ofMinutes(5))
    .modelName("mistral:7b")
    .build()

var chatMemory = MessageWindowChatMemory.withMaxMessages(10)

var bot = AiServices.builder(HolidayBot)
    .chatModel(model)
    .chatMemory(chatMemory)
    .build()

var prompt = '''
What are 4 interesting things to do for a weekend away in Caloundra?
Return holiday activity suggestions as structured JSON matching Itinerary.
Give a description, location, day of weekend, and suggested time of day for each of the four activities.
'''
var response = bot.extractActivitiesFrom(prompt)

var prompt2 = '''
If my only spare time is Sunday morning, and I can only go to one activity, which would you recommend?
'''
var response2 = bot.extractActivitiesFrom(prompt2)

println """
Four things:
${response.join('\n')}

Best thing:
${response2.join('\n')}
"""

@ToString(includePackage = false)
record Activity(String activity, String location, String day, String time) {
}

Four things:
Activity(Visit Kings Beach, Kings Beach, Caloundra, Saturday, Morning/Afternoon)
Activity(Explore the Coastal Walk from Bulcock Beach to Shelly Beach, Bulcock Beach to Shelly Beach, Caloundra, Saturday, Early Afternoon/Late Afternoon)
Activity(Relax at the Day Spa on Golden Beach, Golden Beach, Caloundra, Sunday, Morning/Afternoon)
Activity(Enjoy Sunset Dinner Cruise, Pelican Waters or Mooloolaba, Caloundra, Sunday, Late Afternoon/Evening)

Best thing:
Activity(Relax at the Day Spa on Golden Beach, Golden Beach, Caloundra, Sunday, Morning)

interface HolidayAssistantTools {
    String chat(String message)
}

@Tool("The LocalDate of the start of the coming weekend")
LocalDate getWeekend() {
    LocalDate.now().with(TemporalAdjusters.nextOrSame(DayOfWeek.SATURDAY))
}

@Field static Integer fakeDay = 0

@Tool('The expected domain.Weather including weather forecast, min and max temperature in Celsius for a given location and LocalDate')
Weather getWeather(String location, LocalDate date) {
    var fakeWeather = [0: [Caloundra: new Weather('Sunny and Hot', 30, 37)],
                       1: [Caloundra: new Weather('Raining', 5, 15)]]
    fakeWeather[fakeDay++ % fakeWeather.size()][location]
}

var model = OllamaChatModel.builder()
    .baseUrl("http://localhost:11434")
    .timeout(Duration.ofMinutes(5))
    .modelName("qwen3:8b")
//    .logRequests(true)
//    .logResponses(true)
    .build()

var chatMemory = MessageWindowChatMemory.withMaxMessages(10)

var assistant = AiServices.builder(HolidayAssistantTools)
    .chatModel(model)
    .chatMemory(chatMemory)
    .tools(this)
    .build()

var prompt = '''
Recommend an interesting thing to see in Caloundra for each day of this coming weekend.
Factor in expected weather when making recommendations. Do not hallucinate weather or dates.
'''
var response = assistant.chat(prompt)

println """
Preparing recommendations as at: ${LocalDate.now()}
Interesting things:
$response
"""

@ToString(includePackage = false)
record Weather(String forecast, int minTemp, int maxTemp) {
}

Preparing recommendations as at: 2025-11-12
Interesting things:
Here’s a weather-aware recommendation for Caloundra this coming weekend (November 15–16, 2025):

**Saturday, November 15 (Sunny & Hot: 30°C–37°C)**
☀️ **Beach Day at Caloundra Spit**
- Explore the scenic Caloundra Spit, a 12km stretch of sand with wildlife, birdlife, and picnic spots.
- Try snorkeling or swimming in the calm waters (avoid midday sun; visit early morning or late afternoon).
- Tip: Stay hydrated, wear sunscreen, and bring a hat.

**Sunday, November 16 (Raining & Cool: 5°C–15°C)**
🌧️ **Indoor Cultural Activities**
- Visit the **Caloundra Art Gallery** or **Caloundra Library** for indoor browsing and local art exhibits.
- Enjoy a cozy café visit (e.g., **The Coffee Bean & Tea Leaf**) with a book or light meal.
- Tip: Pack an umbrella, layer clothing, and prioritize dry footwear.

Safe travels! 🌊📚

@SpringBootApplication
void main() {
    try(var context = SpringApplication.run(Holiday)) {
        var chatClient = context.getBean(ChatClient.Builder).build()
        println chatClient
                .prompt("What are four interesting things to do while I am on vacation in Caloundra?")
                .call()
                .content()
    }
}

 Caloundra, located on the Sunshine Coast of Australia, offers a variety of activities that cater to different interests. Here are some suggestions for an enjoyable vacation:

1. Beaches: Caloundry has several beautiful beaches, including Kings Beach, Moffat Beach, and Bulcock Beach. You can swim, sunbathe, surf, or just enjoy the stunning views.

2. Visit the Underwater World SEA LIFE Mooloolaba: This aquarium is home to a diverse range of marine life, including sharks, turtles, and seahorses. It's a great place for both children and adults to learn about and interact with marine creatures.

3. Explore the Glass House Mountains: These are a series of 12 granite peaks that offer stunning views of the surrounding area. You can hike, picnic, or simply enjoy the panoramic vistas.

4. Visit the Eumundi Markets: Open on Saturdays and Wednesdays, these markets feature over 600 stalls selling art, crafts, produce, and food. It's a great place to pick up unique souvenirs and sample local delicacies.

record Itinerary(List<Activity> itinerary) {
    String display() {
        itinerary.join('\n')
    }
}

@SpringBootApplication
void main() {
    try(var context = SpringApplication.run(Holiday)) {
        var chatClient = context.getBean(ChatClient.Builder).build()
        var response = chatClient
                .prompt("What are some interesting things to do while over a long weekend in Caloundra?")
                .call()
                .entity(Itinerary)
        println "Response:\n" + response.display()
    }
}

Response:
Activity(Visit Kings Beach, Caloundra, Day 1, Morning)
Activity(Explore Bulcock Beach, Caloundra, Day 1, Afternoon)
Activity(Sunset at Moffat Headland, Caloundra, Day 1, Evening)
Activity(Visit the Australian Zoo, Beerwah, Day 2, Whole Day)
Activity(Relax at Shelly Beach, Caloundra, Day 3, Morning)
Activity(Explore Pumicestone Passage by boat tour, Caloundra, Day 3, Afternoon)

@Component
class WeekendTool {
    @Tool(description = 'The LocalDate of the start of the coming weekend')
    LocalDate getWeekend() {
        LocalDate.now().with(TemporalAdjusters.nextOrSame(DayOfWeek.SATURDAY))
    }
}

@Component
class WeatherTool {
    static Integer fakeDay = 0

    @Tool(description = 'The expected weather including forecast, min and max temperature in Celsius for a given location and LocalDate')
    Weather getWeather(String location, LocalDate date) {
        var fakeWeather = [0: [Caloundra: new Weather('Sunny and Hot', 30, 37)],
                           1: [Caloundra: new Weather('Raining', 5, 15)]]
        fakeWeather[fakeDay++ % fakeWeather.size()][location]
    }
}

@SpringBootApplication
void main() {
    var prompt = '''
Recommend an interesting thing to see in Caloundra for each day of this coming weekend.
Factor in expected weather when making recommendations. Do not hallucinate weather or dates.
'''
    try(var context = SpringApplication.run(Holiday)) {
        var chatClient = context.getBean(ChatClient.Builder).build()
        var weekend = context.getBean(WeekendTool)
        var weather = context.getBean(WeatherTool)
        var options = OllamaChatOptions.builder().model('qwen3:8b')
        println chatClient
                .prompt(prompt)
                .options(options)
                .tools(weekend, weather)
                .call()
                .content()
    }
}

**Saturday, November 15 (Sunny & Hot: 30°C–37°C)**
Perfect for outdoor adventures!
- **Caloundra Spit** – Explore the scenic coastal walk with panoramic ocean views.
- **Snorkeling at Mooloolaba Beach** – Clear waters and vibrant marine life.
- **Glass House Mountains Day Trip** – A short drive offers dramatic landscapes and hiking.

**Sunday, November 16 (Raining: 5°C–15°C)**
Opt for indoor attractions or sheltered activities:
- **Caloundra Cultural Centre** – Discover local art and history.
- **Caloundra Regional Gallery** – Enjoy contemporary exhibitions.
- **Indoor Water Playground** – A splash-filled escape from the rain.

Always check for real-time weather updates closer to the date! 🌞🌧️

@SpringBootApplication
@EnableAgents(loggingTheme = LoggingThemes.STAR_WARS)
void main() {
    try(var context = SpringApplication.run(Holiday)) {
        println context.getBean(OperationContext)
            .ai()
            .withDefaultLlm()
            .generateText('What are four interesting things to do while I am on vacation in Caloundra?')
    }
}

 1. Visit the Bulcock Beach: This is a popular beach in Caloundra, perfect for swimming, sunbathing, and enjoying various water sports. There's also a picturesque esplanade with cafes, shops, and art galleries nearby.

2. Explore the Kings Beach Park: Located next to Kings Beach, this park offers a variety of facilities including picnic areas, BBQ facilities, playgrounds, and beautiful views of the ocean. It's a great spot for families with children.

3. Visit the Australian Zoo: Made famous by Steve Irwin, the Australian Zoo is just a short drive from Caloundra. Here you can see a wide variety of Australian wildlife, including kangaroos, koalas, and crocodiles.

4. Take a day trip to the Glass House Mountains: These are a series of 13 steep sided, volcanic plugs that dominate the local landscape. You can hike some of the mountains, or simply enjoy their unique beauty from various lookout points. Some popular ones include Mount Ngungun and Mount Beerwah.

@SpringBootApplication
@EnableAgents(loggingTheme = LoggingThemes.STAR_WARS)
void main() {
    try(var context = SpringApplication.run(Structured)) {
        println context.getBean(OperationContext)
            .ai()
            .withDefaultLlm()
            .createObject('What are some interesting things to do while I am on vacation in Caloundra?', Itinerary)
            .display()
    }
}

Activity(Visit the Kings Beach, Kings Beach, Caloundra, Day 1, Morning)
Activity(Explore Bulcock Beach, Bulcock Beach, Caloundra, Day 1, Afternoon)
Activity(Dine at Mooloolaba Seafood Market, Mooloolaba Seafood Market, Mooloolaba, Day 1, Evening)
Activity(Visit the Aussie World Theme Park, Aussie World, Palmview, Day 2, Whole day)
Activity(Relax at Shelly Beach, Shelly Beach, Caloundra, Day 3, Morning)
Activity(Try Surfing at Currimundi Beach, Currimundi Beach, Currimundi, Day 3, Afternoon)
Activity(Explore the Eumundi Markets, Eumundi Markets, Eumundi, Day 4, Morning to Afternoon)

record Alternatives(Set<Itinerary> content) {
}

record RatedAlternatives(List<RatedItinerary> content) {
}

record RatedItinerary(Itinerary itinerary, Rating rating) {
}

record Rating(double percentage) { }

@Agent(description = "Creates and ranks itineraries for a holiday at a given location")
class ItineraryAgent {
    @Action
    Alternatives generateItineraries(UserInput userInput, OperationContext context) {
        context.ai()
            .withLlm('qwen3:8b')
            .createObject("Generate 5 alternative sets of: $userInput.content?", Alternatives)
    }

    @Action
    RatedAlternatives rateItineraries(Alternatives alternatives, OperationContext context) {
        new RatedAlternatives(alternatives.content.collect { itinerary ->
            var rating = context.ai()
                .withLlm('mistral:7b')
                .createObject("Rate this itinerary on variety and number of activities: $itinerary?", Rating)
            new RatedItinerary(itinerary, rating)
        })
    }

    @Action
    @AchievesGoal(description = 'Best itinerary')
    RatedItinerary bestItinerary(RatedAlternatives ratedAlternatives) {
        ratedAlternatives.content.max { it.rating.percentage }
    }
}

@SpringBootApplication
@EnableAgents(loggingTheme = LoggingThemes.STAR_WARS)
void main() {
    try(var context = SpringApplication.run(Rated)) {
        println context.getBean(Autonomy)
            .chooseAndRunAgent('Itinerary for a relaxing long-weekend holiday in Caloundra', ProcessOptions.DEFAULT).output
    }
}

RatedItinerary[
    itinerary=Itinerary[itinerary=[
        Activity(Arrival, Caloundra, Friday, Afternoon),
        Activity(Kings Beach Leisure Park, Kings Beach, Friday, Evening),
        Activity(Dinner at Bulcock Street Tavern, Caloundra, Friday, Night),
        Activity(Explore Powerboat Racing Complex, Caloundra, Saturday, Morning),
        Activity(Lunch at Point Cartwright, Point Cartwright, Saturday, Afternoon),
        Activity(Sunset Yoga on Mooloolaba Beach, Mooloolaba Beach, Saturday, Evening),
        Activity(Dinner at Ricky's River Bar & Restaurant, Eumundi, Saturday, Night),
        Activity(Visit the Ginger Factory, Yandina, Sunday, Morning),
        Activity(Relax at Golden Beach, Golden Beach, Sunday, Afternoon),
        Activity(Farewell Dinner, Caloundra, Sunday, Evening),
        Activity(Departure, Caloundra, Monday, Morning)]],
    rating=Rating[percentage=90.0]]

@Singleton
class AppRunner {
    @Inject
    HolidayAssistant assistant

    void run() {
        println assistant.activities('What are four good things to see while I am in Auckland?')
    }
}

@AiService
interface HolidayAssistant {
    @SystemMessage('''
    You are knowledgeable about places tourists might like to visit.
    Answer using New Zealand slang but keep it family friendly.
    ''')
    String activities(String userMessage)
}

try(var context = ApplicationContext.run()) {
    context.getBean(AppRunner).run()
}

 Blimey mate, while you're roaming around Auckland, here are four top-notch spots ya gotta check out:

1. The Sky Tower - It's like the tallest bloke in town, with a view that'll make ya heart race.
2. Waitomo Glowworm Caves - It's a magical spot where tiny luminescent critters put on a light show.
3. Waiheke Island - A chilled-out paradise with beaches and vineyards, perfect for a day trip or longer stay.
4. Auckland Zoo - Get up close and personal with some of New Zealand's native critters, as well as exotic animals from around the world. Kiwi, eh?

@AiService
interface HolidayBot {
    @SystemMessage('''
    Return holiday activity suggestions as structured JSON matching Itinerary.
    Timebox activities if needed to fit within the holiday length and not overlap other
    activities while still giving enough time to see all major aspects of each attraction.
    Exclude other information.
    ''')
    Itinerary itinerary(String userMessage)
}

try(var context = ApplicationContext.run()) {
    println context.getBean(HolidayBot)
        .itinerary('Four great things to see in Auckland over a weekend.')
        .display()
}

Activity(Visit Auckland War Memorial Museum, Auckland, Day 1, 9:00 AM - 5:00 PM)
Activity(Explore Viaduct Harbour and Wynyard Quarter, Auckland, Day 1, 6:00 PM - 8:00 PM)
Activity(Hike up Mount Eden, Auckland, Day 2, 9:00 AM - 12:00 PM)
Activity(Visit Waiheke Island and its vineyards, Waiheke Island, Day 2, 1:00 PM - 6:00 PM)

@Singleton
class WeekendTool {
    @Tool("The LocalDate of the coming weekend")
    LocalDate getWeekend() {
        LocalDate.now().with(TemporalAdjusters.nextOrSame(DayOfWeek.SATURDAY))
    }
}

@Singleton
class WeatherTool {
    @Tool('Gets the expected weather forecast including temperature for a given city and LocalDate')
    Weather getWeather(String city, LocalDate date) {
        println "Looking up weather for $city on $date"
        var fakeWeather = [Auckland: new Weather('sunny', 16, 26),
                           'Mt Hutt': new Weather('hot', 30, 38)]
        fakeWeather[city]
    }
}

@AiService(tools = [WeatherTool, WeekendTool])
interface WeatherAwareBot {
    @SystemMessage('''
    You are a travel planning assistant that helps users plan activities for their holidays.
    Before finalizing the itinerary, use the WeatherTool tool for each destination city and each day of the itinerary.
    Use the WeatherTool by creating a JSON object:
    { "tool": "getWeather", "arguments": { "city": "...", "date": "YYYY-MM-DD" } }
    Only after getting results from the tool, produce final Itinerary JSON.
    Use the WeekendTool to work out the date for "the coming weekend".
    Use the tool information to adjust your activity suggestions accordingly.
    Return only an Itinerary JSON structure.
    ''')
    Itinerary chat(String userMessage)
}

try(var context = ApplicationContext.run()) {
    var bot = context.getBean(WeatherAwareBot)
    println bot
        .chat('Four great things to see in Auckland this coming weekend.')
        .display()
    println bot
        .chat('A few things to do in Mt Hutt this coming weekend.')
        .display()
}

Activity(Auckland Museum, 155 Queen Street, Auckland, 2025-11-14, 10:00 AM)
Activity(Beachside Stroll, Mission Bay Beach, 2025-11-14, 3:00 PM)
Activity(Harbour Bridge Walk, Auckland Harbour Bridge, 2025-11-15, 9:00 AM)
Activity(Sky Tower Panorama, Sky Tower, 666 Queen Street, 2025-11-15, 2:00 PM)

Activity(Mt Hutt Summit Walk, Mt Hutt Summit Track, 2025-11-15, 9:00 AM)
Activity(Lake Hutt Picnic, Lake Hutt, 2025-11-15, 1:00 PM)
Activity(Scenic Drive to Tutea Valley, Tutea Valley, Mt Hutt, 2025-11-16, 10:00 AM)
Activity(Water Activities at Lake Hutt, Lake Hutt, 2025-11-16, 2:00 PM)

./gradlew :micronaut:nativeToolsCompile
micronaut/build/native/nativeToolsCompile/tools

./gradlew run.micronaut.Holiday run.micronaut.Structured run.micronaut.Tools -Pagent
./gradlew :micronaut:metadataCopy

@RegisterAiService
@ApplicationScoped
interface HolidayAssistant {
    @SystemMessage('You are knowledgeable about places tourists might like to visit.')
    String ask(@UserMessage String question)
}

@QuarkusMain
class Holiday implements QuarkusApplication {

    @Inject
    HolidayAssistant assistant

    @Override
    int run(String... args) {
        def question = 'What are four things to do while visiting Minneapolis?'
        println "Asking: $question"
        def answer = assistant.ask(question)
        println "Answer: $answer"
        return 0
    }
}

Asking: What are four things to do while visiting Minneapolis?
Answer:  1. Explore the Minneapolis Sculpture Garden: This 11-acre outdoor museum located in downtown Minneapolis is home to over 40 works of art, including the iconic "Spoonbridge and Cherry" sculpture. The garden also features walking trails, picnic areas, and a conservatory.

2. Visit the Mill City Museum: Located in the former Washburn A Mill, this museum tells the story of Minneapolis' milling heritage. You can explore exhibits on the city's flour-milling past, take a tour of the restored flour mill elevators, and enjoy panoramic views of the Mississippi River from the rooftop observation deck.

3. Stroll through the Minnehaha Park: This beautiful urban park features hiking trails, a waterfall, and breathtaking views of the Mississippi River. You can also visit Minnehaha Falls, a 53-foot waterfall that is one of the most popular attractions in Minneapolis.

4. Attend a concert or sporting event: Minneapolis is home to several major sports teams, including the Minnesota Vikings (NFL), Minnesota Timberwolves (NBA), and Minnesota Twins (MLB). The city also has a thriving music scene, with venues like First Avenue and the Orpheum Theatre hosting concerts by popular artists. Additionally, the Walker Art Center offers free outdoor performances during the summer months at its Sculpture Garden.